Kurvendiskussion

(%i1) f(x) := 1/12*x^4-2/3*x^3;
f1(x) := ''(diff(f(x),x));
f2(x) := ''(diff(f1(x),x));
f3(x) := ''(diff(f2(x),x));

Globale Eigenschaften

(%i5) if is(f(-x)=f(x)) then
    print("f ist ist elementar achsensysmmetrisch")
else if is(f(-x)=-f(x)) then
    print("f ist ist elementar punktsysmmetrisch")
else
    print("f ist nicht elementar symmetrisch")$

(%i6) links : limit(f(x), x, -inf)$
rechts : limit(f(x), x, inf)$
if links=-inf and rechts=-inf then
    print("f kommt von unten und geht nach unten")
else if links=-inf and rechts=+inf then
    print("f kommt von unten und geht nach oben")
else if links=inf and rechts=-inf then
    print("f kommt von oben und geht nach unten")
else if links=inf and rechts=inf then
    print("f kommt von oben und geht nach oben")$

(%i9) rand(x) := part(f(x),1)$
mitte(x) := part(f(x),nterms(f(x)))$
print("f verläuft am Rand wie ", rand(x), " in der Mitte wie ", mitte(x))$

--> plot2d(
    [f(x), rand(x), mitte(x)], [x,-10,10], [y,-10,10],
    [box, false],
    [plot_format, xmaxima]
);
/* Grafikfenster wieder schließen! */

(%i13) wxdraw2d(
    color=red,explicit(rand(x),x,-10,-5),explicit(rand(x),x,5,10),
    color=red,explicit(mitte(x),x,-5,5),
    color=blue,explicit(f(x),x,-10,10)
)$

Nullstellen

(%i14) Nf : solve(f(x)=0);

Extrema

(%i15) Nf1 : solve(f1(x)=0)$
print("mögliche Extremstellen sind", Nf1)$

(%i17) for i : 1 thru length(Nf1) do (
    t : rhs(Nf1[i]),
    ft : f(t),
    f2t : f2(t),
    if f2t<0 then
        print(t, " ist Hochstelle; Hochpunkt H", [t,ft])
    else if f2t>0 then
        print(t, " ist Tiefstelle; Tiefpunkt T", [t,ft])
    else
        print("Die Lage an der Stelle ", t, " ist noch unklar")
)$

Wendepunkte

(%i18) Nf2 : solve(f2(x)=0)$
print("mögliche Wendestellen sind", Nf2)$

(%i20) for i : 1 thru length(Nf2) do (
    t : rhs(Nf2[i]),
    ft : f(t),
    f1t : f1(t),
    f3t : f3(t),
    if f3t<0 then
        print(t, " ist Wendestelle (li-re); W", [t,ft], " m=", f1t)
    else if f3t>0 then
        print(t, " ist Wendestelle (re-li); W", [t,ft], " m=", f1t)
    else
        print("Die Lage an der Stelle ", t, " ist noch unklar")
)$

Created with wxMaxima.